Section 17.5: Diffusion into a Falling Liquid Film:

Forced Convection Mass Transfer

Bird, Stewart, and Lightfoot. Transport Phenomena. John Wiley and Sons. 1960.

A Project by Amanda Watford & Judy Hsii

_______________________________________________________________________________

This section of the text deals with an illustration of forced-convection mass transfer. The conditions under which the viscous flow and diffusion occur allow the velocity field to be viturally unaffected by diffusion. The absorption of gas A can then be considered by a laminar falling film of liquid B. Some of the assumptions and restrictions are as follows:

· Material A is only slightly soluble in material B.

This makes the viscosities not change appreciably.

· Diffusion takes place very slowly in the film.

Material A willl thus not infiltrate a great distance into material B.

The penetration distance will be small relative to the thickness of the film.

Using Maple V, we hope to setup the equations that are indicative of the process described above.

We start by establishing a mass balance on component A. The concentration of A, cA, will change with both x and z.

_______________________________________________________________________________

> restart; An essential command at the start of each new Maple worksheet.

We start by first defining Az and Ax. Az and Ax are cross-sectional areas. W is the width of the film.

> Az:=W*dx; Ax:=W*dz;

We then imput the mass balance on component A. This equation is equal to zero. cA changes both with x and with z.

> eq:=(NAz(x,z)-NAz(x,z+dz))*Az + (NAx(x,z)-NAx(x+dx,z))*Ax;

The limit is taken as dx goes to zero.

> eq2:=limit(eq/(W*dx*dz),dx=0);

The limit of the previous equation, eq2, is taken as dz goes to zero. The resulting equation is equal to zero and matches Eqn 17.5-3 of the BSL text.

> pde:=-limit(eq2,dz=0)=0;

Material A moves in the z direction due to the flow of the film. In the z direction, the convective term dominates and the diffusive term is negligible. Thus Eqn 17.0-1 reduces to xA*(NAz+NBz), but this can be rewritten as cA*vz as long as vz is taken to be the molar average velocity. See Table 16.1-3. The assumption that the molar average velocity and the mass average velocity are identical is another approximation in the problem.

> NAz:=(x,z)->vz(x)*cA(x,z);

Material A moves in the x-direction due to diffusion and the convective term is negligible. Thus Eqn 17.0-1 reduces to –DAB dcA/dx for the x direction.

> NAx:=(x,z)->-DAB*D[1](cA)(x,z);

This equals Eq. 17.5-6 of the BSL text.

> pde;

Pdsolve does not solve the partial differential equation as we would like. Therefore we will enter the book’s solution and see if we can work backwards to make it match our partial differential equation, pde.

The book's solution from Eqn 17.5-15.

> cA:=(x,z)->cA0*(1-erf(x/sqrt(4*DAB*z/vmax)));

Substance A only penetrates a short distance into the film and thus for most parts, the velocity of the film to equal vmax.

> vz:=x->vmax;

> D[2](NAz)(x,z);

Take the derivative of NAz with respect to z.

> diff(NAz(x,z),z);

> simplify(pde); Simplify pde from above.

The sum of these derivatives equals zero. Thus Eqn 17.5-3 of the BSL text is satisfied.

> simplify(diff(NAz(x,z),z)+diff(NAx(x,z),x));

Boundary Condition # 1, Eq. 17.5-12 of the text. According to the figure, the concentration of A is zero when z approaches zero from the right.

> limit(cA(x,z),z=0,right);

Assume all values are positive to simplify the solving of this problem. Physically, positive values make logical sense as well.

> assume(DAB>0,vmax>0,x>0,z>0);

The limit is taken again after the variables are assumed to be positive.

> limit(cA(x,z),z=0,right);

Boundary Condition #2, Eq. 17.5-13 of the text. At x=0, cA is at its initail concentration.

> cA(0,z);

BC 3 eq. 17.5-4. At x= infinity, the concentration of A is zero.

> limit(cA(x,z),x=infinity);

Now we will integratethe mass flux over the length of the film. But first, we need to clear all assumptions made previously.

> restart;

Eqn 17.5-15 of the BSL text.

> cA:=(x,z)->cA0*(1-erf(x/sqrt(4*DAB*z/vmax)));

NAx is redefined using the assumption that the convective term in Eqn 17.0-1 is negligible.

> NAx:=(x,z)->-DAB*D[1](cA)(x,z);

The local mass flux at x=0 is found which resembles Eqn. 17.5-16 of the text.

> NAx(0,z);

The total moles of A transferred per unit time from the gas to the liquid film is found. This is based on Eqn 17.5-17 of the text.

> WA:=W*int(NAx(0,z),z=0...L);

We now combine the solution found above, and compare it to Eqn. 17.5-17 of the BSL text.

> combine(%);

We further show that the solution is the same as that given in the text by subtracting Eqn 17.5-17 from the solution above and simplifying.

> simplify(%-W*L*cA0*sqrt(4*DAB*vmax/Pi/L),assume=positive);

As the difference between the solution calculated and the solution given in the text, we have verified the derivation in the text using Maple V.

In order to apply the concepts discussed in this section of the BSL text, an Example 17.5-1 will also be shown using Maple V. For the derivation, click here.