THE DERIVATION OF THE NABLA OPERATOR AND THE SPATIAL DERIVATIVES OF THE UNIT VECTORS FOR CYLINDRICAL COORDINATES

Work done by Scott Covan

To make any vector calculations in a given coordinate system, p.733 of the text clearly states that all we need is "(a) the expression for nabla in the curvilinear coordinates, and (b) the spatial derivatives of the unit vectors in curvilinear coordinates." We will do this here for cylindrical coordinates, based on r, theta, and z. This involves transforming the nabla operator we have already defined for rectangular coordinates (d/dx*delx + d/dy*dely + d/dz*delz) into cylindrical coordinates. In this derivation we will use the term "del" plus a variable name (ex: delx) to signify the unit vector in that variable direction, and "dd" plus a variable name (ex: ddx) to signify the differential operator for that variable (ex: d/dx).

First, we need nabla. We'll begin by calculating d/dx in terms of the unit vectors for r, theta, and z. Z as defined in recangular coordinates is the same as it is defined in cylindrical coordinates, so it doesn't really change. We will leave it out of most of our calculations. Eqns A.6-(1-6) state:

x=rcos(theta) r=sqrt(x^2+y^2)

y=rsin(theta) theta=arctan(y/x)

z=z z=z

To get d/dx, we use the chain rule of partial differentiation, which, in this case, states that,

d/dx = dr/dx*d/dr + dtheta/dx*d/dtheta + dz/dx+d/dz

> restart;

> ddx:=ddr*diff(sqrt(x^2+y^2),x)+ddtheta*diff(arctan(y/x),x);

Now we substitute in our eqns for x and y in terms of cylindrical coordinates.

> ddx:=subs(x=r*cos(theta),y=r*sin(theta),ddx);

Maple won't simplify this properly unless we specify that we want its trig simplification procedures used

> ddx:=simplify(ddx,trig);

Again, Maple won't simplify this well unless we tell it use "power, symbolic" simplification to get rid of the radical. Specifiying "radical" simplification won't do it either.

> ddx:=simplify(ddx,power,symbolic);

We want the terms separate.

> ddx:=expand(ddx);

This looks like eqn A.6-7. Now lets go through the exact same calculations to acquire d/dy. (We already know d/dz stays the same.)

> ddy:=ddr*diff(sqrt(x^2+y^2),y)+ddtheta*diff(arctan(y/x),y);

> ddy:=subs(x=r*cos(theta),y=r*sin(theta),ddy);

> ddy:=expand(simplify(ddy,trig,power,symbolic));

This matches eqn A.6-8. Now, to finish getting nabla, we need to get the definitions of the unit vectors for x, y, and z in terms of r, theta, and z. To do this, we first use simple geometrical arguments, based on the two coordinate system definitions, to state eqns A.6-(10-12):

delr = cos(theta)delx + sin(theta)dely

deltheta = -sin(theta)delx + cos(theta)dely

delz = delz

We now use Maple and its solver to solve for delr and dely (delz stays the same).

> eqn1:=delr=cos(theta)*delx+sin(theta)*dely;eqn2:=deltheta=-sin(theta)*delx+cos(theta)*dely;

> e:=solve({eqn1,eqn2},{delx,dely});

It worked. We now want to use these results, so we pull them out using the subs command.

> delx:=subs(e,delx);dely:=subs(e,dely);

The nabla operator is defined by eqn A.3-1. In this case,

nabla = delx*d/dx + dely*d/dy + delz*d/dz

We plug our results into this eqn.

> nabla:=ddx*delx+ddy*dely+ddz*delz;

> nabla:=simplify(nabla);

> nabla:=expand(nabla);

This matches eqn A.7-5. Now we need to get the spatial derivatives of the unit vectors in our new coordinates. We will restart to avoid recursive definitions, and redefine delr, deltheta, and delz as they were stated above.

> restart;delr:=cos(theta)*delx+sin(theta)*dely;deltheta:=-sin(theta)*delx+cos(theta)*dely;delz:=delz;

> diff(delr,r);diff(delr,theta);diff(delr,z);

These are the spatial derivatives of delr. We should notice that d/dtheta(delr) is equal to deltheta.

> diff(deltheta,r);diff(deltheta,theta);diff(deltheta,z);

The spatial derivatives of deltheta. Here again, we should see that d/dtheta(deltheta) is equal to -delr.

> diff(delz,r);diff(delz,theta);diff(delz,z);

The spatial derivatives of z. We now have the two pieces of knowledge needed to do vector calculations in cylindrical coordinates. More importantly, we can now derive the equations of energy in terms of cylindrical coordinates.