THE DERIVATION OF THE ENERGY EQUATION IN CYLDINRICAL COORDINATES

Work done by Scott Covan

We already derived the nabla operator and the partial derivatives for the unit vectors in cylindrical coordinates. Now we want to derive the equation of energy in terms of cylindrical coordinates, Table 10.2-2(B). To do this, we consider eqn 10.1-19,

rho*Cv*DT/Dt = -(nabla dot q) - T(dp/dt)(nabla dot v) - (tau: nabla*v)

The left-hand side is straightforward, and the T(dp/dt) stays unchanged. There are three terms we must evaluate, and these are the two "dotted" terms and the (tau: nabla*v). The two dotted terms will have the exact same form. We will calculate here the (nabla dot v) term, but by changing each "v" to a "q", one obtains the (nabla dot q) term. Remember, ddr represents d/dr, and delr represents the unit vector in the r direction.

> restart;

This is our nabla term in cylindrical coordinates.

> nabla:=delr*ddr+deltheta/r*ddtheta+delz*ddz;

This is our v vector (in the same form as the q vector).

> V:=delr(r,theta,z)*Vr(r,theta,z) + deltheta(r,theta,z)*Vtheta(r,theta,z) + delz(r,theta,z)*Vz(r,theta,z);

Because Maple is very sensitive when it comes to simplification, we will define (nabla dot v) as a vector of three terms and expand each one. The entire thing can be simplified without combining terms.

> NABdotV:=expand([delr(r,theta,z)*diff(V,r),deltheta(r,theta,z)*diff(V,theta)/r,delz(r,theta,z)*diff(V,z)]);

We will now substitute in all nine partial derivatives that belong to the cylindrical system. These are,

d/dr(delr)=0 d/dr(deltheta)=0 d/dr(delz)=0

d/dtheta(delr)=deltheta d/dtheta(deltheta)=-delr d/dtheta(delz)=0

d/dz(delr)=0 d/dz(deltheta)=0 d/dz(delz)=0

> NABdotV:=subs(diff(delr(r,theta,z),r)=0,diff(delr(r,theta,z),theta)=deltheta(r,theta,z),diff(delr(r,theta,z),z)=0,diff(deltheta(r,theta,z),r)=0,diff(deltheta(r,theta,z),theta)=-delr(r,theta,z),diff(deltheta(r,theta,z),z)=0,diff(delz(r,theta,z),r)=0,diff(delz(r,theta,z),theta)=0,diff(delz(r,theta,z),z)=0,NABdotV);NABV:=NABdotV[1]+NABdotV[2]+NABdotV[3]:

Even though, so far, we have treated the del terms as if they have been multiplied together, they have actually all been "dotted" together. This means we can substitute into (nabla dot v) the fact that a unit vector dotted with itself is 1.

> NABdotV:=subs(delr(r,theta,z)^2=1,deltheta(r,theta,z)^2=1,delz(r,theta,z)^2=1,NABdotV);

Unfortunately, Maple doesn't want to substitute any of the cross terms, so algsubs must be used. Since algsubs will accept only one substitution at a time, we can embed the three substitutions we want to make inside each other. These substitutions are based on the fact that a unit vector dotted with a different unit vector is equal to zero.

> NABdotV:=algsubs(deltheta(r,theta,z)*delz(r,theta,z)=0,algsubs(delr(r,theta,z)*delz(r,theta,z)=0,algsubs(delr(r,theta,z)*deltheta(r,theta,z)=0,NABdotV)));

We now expand these terms after taking them out of a vector and summing them.

> NABdotV:=expand(NABdotV[1]+NABdotV[2]+NABdotV[3]);

This should look like the (nabla dot v) and (nabla dot q) terms in Table 10.2-2(B). Now, earlier on, after we substituted the partial derivatives into the equation for (nabla dot v), we defined another term, called NABV, that is now to represent the nabla*v term within the (tau: nabla*v) term. Up to that point, calculation of nabla*v and (nabla dot v) were similar. Here they depart. Here, delr^2 is actually delr*delr, not (delr dot delr).

> NABV;

Not as many terms will disappear now. Where we have delr^2, we will substitute the TAUrr term that will appear in the final answer.

> NABV:=subs(delr(r,theta,z)^2=TAUrr,deltheta(r,theta,z)^2=TAUthetatheta,delz(r,theta,z)^2=TAUzz,NABV);

Again, Maple doesn't want to substitute for the cross terms. In addition, this function, for whatever reason, requires that each algsubs occurs on separate lines. We can't embed them, but we can execute them all on one line.

> NABV:=expand(algsubs(deltheta(r,theta,z)*delz(r,theta,z)=TAUthetaz,NABV)):NABV:=expand(algsubs(delr(r,theta,z)*delz(r,theta,z)=TAUrz,NABV)):NABV:=expand(algsubs(delr(r,theta,z)*deltheta(r,theta,z)=TAUrtheta,NABV));

Maple won't simplify this as we want it simplified, but if TAU terms are collected by hand, this answer becomes the last term in Table 10.2-2(B). We have now derived all the pieces of the equation of energy for cylindrical coordinates.