This section of Bird, Stewart, and Lightfoot examines heat conduction in a spherical nuclear fuel element.  It consists of a fissionable material, the heat source, with a radius RF, surrounded by a sphere of aluminum cladding with an outer radius of RC (see figure), and an outer temperature of To. I begin by defining the source of thermal energy, Sn and then derive expressions for the heat flux in the fissionable material, the heat flux in the cladding, the temperature profile in the cladding and the temperature profile in the fissionable material.
 
 

The Maple derivation of the equations:

Section 9.3 -- Heat Conduction with a Nuclear Heat Source

> restart;

> Sn:=r->Sno*(1+b*(r/RF)^2); This is equation 9.3-1
 
 

> A:=r->4*Pi*r^2; Area of the shell around which the balance is being made.
 
 

> Q:=r->q(r)*A(r); General expression for thermal energy.
 
 

> lefths:=limit((Q(r+dr)-Q(r))/dr,dr=0);
 
 

> de:=lefths=Sn(r)*A(r); Equivalent to equation 9.3-6.
 
 

> cladding:=lefths=0; This is the expression for thermal energy in the cladding, in which there is no source of nuclear energy.
 
 

> sol:=dsolve({de,q(0)=finite},q(r)); This solves the first differential equation with the constraint that at r=0, q is not infinite (eq. 9.3-10).
 
 

> assign(sol);qf:=unapply(q(r),r); This is the flux in the fissionable material.
 
 

> book93_12:=Sno*(r/3+b*r^3/(RF^2*5));

> simplify(book93_12-qf(r)); This means that qf(r) agrees with equation 9.3-12 in the book.
 

> q:='q';

> sol2:=dsolve({cladding,q(RF)=qf(RF)},q(r)); This solves differential equation in the cladding with the constraint that the two fluxes be equal at the boundary of the cladding and the fissionable material (eq. 9.3-11).

> assign(sol2);qc:=unapply(q(r),r);

> book93_13:=Sno*RF^3*(1/3+b/5)/r^2;
 

> simplify(book93_13-qc(r)); This shows that the expression for qc(r) agrees with that in the book.

> Fourier1:=-kF*diff(TF(r),r)=qf(r); Fourier's law of heat conduction applied to the sphere of fissionable material.
 

> Fourier2:=-kC*diff(TC(r),r)=qc(r); This is Fourier's law of heat conduction applied to the cladding.

> sol3:=dsolve({Fourier2,TC(RC)=To},TC(r)); Solving this differential equation with the boundary condition that at the outer edge of the cladding the temperature is To (eq. 9.3-19).
 

> assign(sol3);TC:=unapply(TC(r),r); An expression for the temperature in the cladding.
 

> righths:=simplify(TC(r)-To); An expression for the temperature profile.
 

> book93_21:=Sno*RF^2/(3*kC)*(1+(3*b/5))*((RF/r)-(RF/RC));
 

> simplify(righths-book93_21); This agrees with the expression in the book (eq. 9.3-21).

> sol4:=dsolve({Fourier1,TF(RF)=TC(RF)},TF(r)); This solves the differential equation given by Fourier's law of heat conduction in the fissionable material with the boundary constraint that the temperature at the boundary of the cladding and the fissionable material be the same (eq. 9.3-18).

> assign(sol4);TF:=unapply(TF(r),r); An expression for the temperature in the fissionable material.

> Righths:=simplify(TF(r)-To); An expression for the temperature profile (comparable to 9.3-20).

> book93_20:=Sno*RF^2/(6*kF)*((1-(r/RF)^2)+3/10*b*(1-(r/RF)^4))+Sno*RF^2/(3*kC)*(1+(3/5*b))*(1-(RF/RC));
 

> simplify(Righths-book93_20); This shows that the answer agrees with equation 9.3-20.