CENG 402:Transport Phenomena

Edward Yen and Edaire Cheng

Chapter 2.3: Flow Through a Circular Tube

Consider steady laminar flow of a liquid of constant density r in a very long tube of length L and radius R. Since the tube is very long, assume that there are no end effects. 

For a system of a cylindrical shell of thickness dr and length L, these are the various contributions to the momentum balance in the z-direction. 

> restart;

Area of cylindrical shell of radius r.

> A:=r->2*Pi*r*L;

Newton's Law of Viscosity.

EQN. 2.3-13

> tau:=-mu*D(Vz)(r);

Momentum Flux through a cylindrical surface of radius r.

> Tau:=r->-mu*A(r)*D(Vz)(r);

Rate of momentum in, across cylindrical surface at r.

EQN. 2.3-1

> Tau(r);

Rate of momentum out, across cylindrical surface at r+dr.

EQN. 2.3-2

> Tau(r+dr);

Rate of momentum in, across annular surface at z=0.

EQN 2.3-3

> Tannular0:=2*Pi*r*dr*Vz(r)*(rho*Vz(r));

Rate of momentum out, across annular surface at z=L.

EQN 2.3-4

> TannularL:=2*Pi*r*dr*Vz(r)*(rho*Vz(r));

Gravity force acting upon cylindrical shell.

EQN. 2.3-5

> FG:=r->A(r)*dr*rho*g;

Pressure force acting upon annular surface at z=0.

EQN.2.3-6

> Press0:=r->2*Pi*r*dr*p0;

Pressure force acting upon annular surface at z=L.

EQN. 2.3-7

> PressL:=r->-2*Pi*r*dr*pL;

Adding all contributions to the momentum balance, taking "in" and "out" to be the positive directions of the axes.

EQN. 2.3-8

Note: The terms for momentum across annular surface cancel out because the fluid is assumed to be incompressible. That is, Vz is the same at z=0 and z=L.

> eq1:=Tau(r)-Tau(r+dr)+Tannular0-TannularL+FG(r)+Press0(r)+PressL(r)=0;

In order to simplify the process of determining a solution for Maple, we split up the left hand side and right hand side of EQN. 2.3-8. Then divide left hand side by 2*Pi*L*dr and take the limit as dr approaches zero.

> LHS:=limit((Tau(r+dr)-Tau(r))/(2*Pi*L*dr),dr=0);

Then divide right hand side by 2*Pi*L*dr as well.

> RHS:=simplify((Tannular0-TannularL+FG(r)+Press0(r)+PressL(r))/(2*Pi*L*dr));

Here we then recombine the two sides.

> eq2:=LHS=RHS;

Solving the second-order differential equation with boundary conditions: Vz(0) is finite and the velocity at R is zero.

> sol:=dsolve({eq2,Vz(R)=0,Vz(0)=finite},Vz(r));

Values for height at point 0 and L of the pipe.

> z0:=0;zL:=L;

Values for pressure at z=0 and z=L.

> p0:=P0+rho*g*z0;pL:=PL+rho*g*zL;

> assign(sol);

The velocity distribution though the pipe, only as a function of radius, and not height.

EQN. 2.3-16

> Vz:=unapply(Vz(r),r);

Cleaning up our answer for Vz(r) by using the maple function "factor."

> factor(Vz(r));

Answer given by the book for Vz(r).

EQN. 2.3-16

> Vzbook:=(P0-PL)*R^2*(1-(r/R)^2)/(4*mu*L);

This shows that the book answer does indeed agree with our answer.

> simplify(Vz(r)-Vzbook);

Showing tau, the momentum flux distribution as a function of r, the radius of the pipe.

EQN. 2.3-12

> tau:=unapply(tau,r);

Maximum velocity occurs when r=0.

EQN 2.3-17

> Vzmax:=factor(Vz(0));

Cross sectional area of pipe

> Cross_sect_A:=int(int(r,r=0..R),theta=0..2*Pi);

Average Velocity of fluid through pipe, calculated by summing all velocities over a cross section, and then dividing by the cross sectional area.

EQN.2.3-18

> Vzavg:=factor(int(int(Vz(r)*r,r=0..R),theta=0..2*Pi)/Cross_sect_A);

Volume Rate of Flow, the product of the cross-sectional area of the pipe and average velocity, Vzavg.

EQN.2.3-19

> Q:=Cross_sect_A*Vzavg;

Force of thee fluid against wetted surface of the pipe EQN.2.3-20

> Fz:=A(R)*tau(R);

>