Example 11.4-5 Free Convection Heat Transfer From a Vertical Plate:
Part a: Deriving the dimensionless equations.
>  restart;
>  with(linalg):
>  v:=(y,z)->vector([vy(y,z),vz(y,z)]);
>  s:=vector([y,z]); The position vector.
>  econt:=diverge(v(y,z),s)=0; The equation of continuity: eq. 11.4-33

>  emot:=evalm(rho*v(y,z)&*grad(vz(y,z),s))=mu*diverge(grad(vz(y,z),s),s)+rho*g*beta*(T(y,z)-T1); The z component of the equation of motion: eq. 11.4-34


>  een:=evalm(rho*Cp*v(y,z)&*grad(T(y,z)-T1,s))=k*diverge(grad(T(y,z)-T1,s),s); Energy equation: eq. 11.4-35

>  with(PDEtools,dchange);

>  tr1:={T=T1+Theta*(T0-T1),z=zeta*H,y=eta*(mu*alpha*H/B)^(1/4),vz=phiz*(B*alpha*H/mu)^(1/2),vy=phiy*(alpha^3*B/(mu*H))^(1/4)}; The five transformations suggested in eqs. 11.4-39 to 43.

>  tr2:={z=zeta*H,y=eta*(mu*alpha*H/B)^(1/4),vz=phiz*(B*alpha*H/mu)^(1/2),vy=phiy*(alpha^3*B/(mu*H))^(1/4)}; In the next step we will need to use only four of the transformations in tr. In fact Maple will object if we try to use all5 in tr1. 
>  newcont:=dchange(tr2,econt,[eta,zeta,phiy(eta,zeta),phiz(eta,zeta)]);
>  simplify(newcont,assume=positive); This gives 11.4-44

>  newmot:=dchange(tr1,emot,[eta,zeta,phiy(eta,zeta),phiz(eta,zeta),Theta(eta,zeta)]);
>  simplify(%,assume=positive);
>  k:=alpha*rho*Cp;beta:=B/(rho*g*(T0-T1));mu:=Pr*k/Cp;
>  simplify(newmot/B,assume=positive); This is the same as 11.4-45 except for the second derivative of phiz wrt zeta. This came from the corresponding term in 11.4-34 that was neglected in the text.


>  newen:=dchange(tr1,een,[eta,zeta,phiy(eta,zeta),phiz(eta,zeta),Theta(eta,zeta)]);
>  simplify(%,assume=positive);
>  simplify(sqrt(Pr*H/(rho*B))*%/(Cp*(T0-T1)));
>  simplify(%,assume=positive); This is identical to eq. 11.4-46 except it includes a term that was neglected in the text.


>  eq:=qavg+int(k*D[1](T)(y,z),z=0...H)/H;

>  tr3:={T=T1+Theta*(T0-T1),z=zeta*H,y=eta*(mu*alpha*H/B)^(1/4)};
>  neweq:=dchange(tr3,eq,[Theta(eta,zeta),eta,zeta]);
>  qavg:=solve(neweq,qavg);
>  simplify(qavg,assume=positive);

>  C:=-int(D[1](Theta)(eta,zeta),zeta=0...1);
>  qav11451a:=k*(T0-T1)*(B/mu/alpha/H)^(1/4)*C; first version of qavg given in the text as 11.4-51

>  simplify(qavg-qav11451a,assume=positive);

>  qav11451d:=C*k/H*(T0-T1)*(Gr*Pr)^(1/4); last equation in 11.4-51.
>  Gr:=rho^2*g*beta*(T0-T1)*H^3/mu^2; One version of the Grashof Number as shown in the last two equations in 11.4-51.
>  simplify(qavg-qav11451d,assume=positive); Completing the derivation of the last equation in 11.4-51
>  Lst:=[[log(.73),.518],[log(1),.535],[log(10),.62],[log(100),.653],[log(1000),.665],[infinity,.67]]; Data given on page 349 of BS&L.
>  plot(Lst); Variation of C with the natural log of Pr. Not a very smooth function.