Section 10.7 Heat Conduction in a Cooling Fin
Rectangular fin of length L, width W and thickness 2*B.

     |   |___________
     |   /          /|
   TW| W/          / |
     | /          /  /   Ta
     |/__________/  /
     |   2*B     | /
     |___________|/
     |<----L---->|
     | z-->
At top and bottom of the fin: q=h*(T(z)-Ta)
Neglect heat loss at the end and on the sides of the fin.
Assume T in the fin varies only in the z direction
Converting the DE to dimensionless form before we solve it.
sec107.mws solves the equations before making them dimensionless.
>  restart;
>  A:=2*B*W; Q:=z->-k*D(T)(z)*A; Area perpendicular to the heat conduction and heat flow over the area.
>  C:=2*W; The area for heat loss from a shell of thickness dz will be C*dz
>  eq := limit((Q(z)-Q(z+dz))/(h*A*dz),dz=0)=h*C*dz*(T(z)-Ta)/(h*A*dz); heat into shell-heat out = heat loss to air with both sides divided by h*A*dz.  
>  with(PDEtools,dchange); Now we change the equation to dimensionless form.
>  trans:={z=zeta*L,T=Ta+Theta*(Tw-Ta)};
>  newde:=dchange(trans,eq,[zeta,Theta(zeta)]); Arguments:
1) the set of transformations
2) the differential equation
3) the new functional ralation
>  L:=N*sqrt(k*B/h); Replacing L with N (dimensionless) as in eq. 10.7-8
>  de2:=simplify(N^2*B*newde/(Tw-Ta)); eq. 10.7-9
[Maple Math]
>  s:=dsolve({de2,Theta(0)=1,D(Theta)(1)=0},Theta(zeta)); Using the BCs eq. 10.7-10 and 11: at the wall T=TW and at the end heat loss is zero.
>  assign(s);Theta:=unapply(Theta(zeta),zeta);
>  simplify(Theta(zeta)-cosh(N*(1-zeta))/cosh(N)); comparing our solution with eq. 10.7-13
>  expand(%,trig);
>  eta:=int(Theta(zeta),zeta=0...1); The effectiveness factor defined in eq. 10.7-15:
the ratio of the heat loss to the heat loss from a fin with the wall temperature over ifs surface.
>  eta:=unapply(simplify(convert(%,trig)),N); This agrees with 10.7-16
[Maple Math]
>  plot(eta(N),N=0.01...2); The effectiveness falls off as N increases
[Maple Plot]